impeller::PassBindingsCacheMTL Struct Reference

Ensures that bindings on the pass are not redundantly set or updated. Avoids making the driver do additional checks and makes the frame insights during profiling and instrumentation not complain about the same. More...

#include <pass_bindings_cache_mtl.h>

Public Member Functions
	PassBindingsCacheMTL ()
	~PassBindingsCacheMTL ()=default
	PassBindingsCacheMTL (const PassBindingsCacheMTL &)=delete
	PassBindingsCacheMTL (PassBindingsCacheMTL &&)=delete
void	SetEncoder (id< MTLRenderCommandEncoder > encoder)
void	SetRenderPipelineState (id< MTLRenderPipelineState > pipeline)
void	SetDepthStencilState (id< MTLDepthStencilState > depth_stencil)
bool	SetBuffer (ShaderStage stage, uint64_t index, uint64_t offset, id< MTLBuffer > buffer)
bool	SetTexture (ShaderStage stage, uint64_t index, id< MTLTexture > texture)
bool	SetSampler (ShaderStage stage, uint64_t index, id< MTLSamplerState > sampler)
void	SetViewport (const Viewport &viewport)
void	SetScissor (const IRect &scissor)

Detailed Description

Ensures that bindings on the pass are not redundantly set or updated. Avoids making the driver do additional checks and makes the frame insights during profiling and instrumentation not complain about the same.

There should be no change to rendering if this caching was absent.

Definition at line 24 of file pass_bindings_cache_mtl.h.

Constructor & Destructor Documentation

PassBindingsCacheMTL() [1/3]

impeller::PassBindingsCacheMTL::PassBindingsCacheMTL ( )

inlineexplicit

Definition at line 25 of file pass_bindings_cache_mtl.h.

{}

~PassBindingsCacheMTL()

impeller::PassBindingsCacheMTL::~PassBindingsCacheMTL ( )

default

PassBindingsCacheMTL() [2/3]

impeller::PassBindingsCacheMTL::PassBindingsCacheMTL ( const PassBindingsCacheMTL &  )

delete

PassBindingsCacheMTL() [3/3]

impeller::PassBindingsCacheMTL::PassBindingsCacheMTL ( PassBindingsCacheMTL &&  )

delete

Member Function Documentation

SetBuffer()

bool impeller::PassBindingsCacheMTL::SetBuffer	(	ShaderStage	stage,
		uint64_t	index,
		uint64_t	offset,
		id< MTLBuffer >	buffer
	)

Definition at line 31 of file pass_bindings_cache_mtl.mm.

                                                           {
  auto& buffers_map = buffers_[stage];
  auto found = buffers_map.find(index);
  if (found != buffers_map.end() && found->second.buffer == buffer) {
    // The right buffer is bound. Check if its offset needs to be updated.
    if (found->second.offset == offset) {
      // Buffer and its offset is identical. Nothing to do.
      return true;
    }
 
    // Only the offset needs to be updated.
    found->second.offset = offset;
 
    switch (stage) {
      case ShaderStage::kVertex:
        [encoder_ setVertexBufferOffset:offset atIndex:index];
        return true;
      case ShaderStage::kFragment:
        [encoder_ setFragmentBufferOffset:offset atIndex:index];
        return true;
      default:
        VALIDATION_LOG << "Cannot update buffer offset of an unknown stage.";
        return false;
    }
    return true;
  }
  buffers_map[index] = {buffer, static_cast<size_t>(offset)};
  switch (stage) {
    case ShaderStage::kVertex:
      [encoder_ setVertexBuffer:buffer offset:offset atIndex:index];
      return true;
    case ShaderStage::kFragment:
      [encoder_ setFragmentBuffer:buffer offset:offset atIndex:index];
      return true;
    default:
      VALIDATION_LOG << "Cannot bind buffer to unknown shader stage.";
      return false;
  }
  return false;
}

SetDepthStencilState()

void impeller::PassBindingsCacheMTL::SetDepthStencilState

(

id< MTLDepthStencilState >

depth_stencil

)

Definition at line 22 of file pass_bindings_cache_mtl.mm.

                                            {
  if (depth_stencil_ == depth_stencil) {
    return;
  }
  depth_stencil_ = depth_stencil;
  [encoder_ setDepthStencilState:depth_stencil_];
}

SetEncoder()

void impeller::PassBindingsCacheMTL::SetEncoder

(

id< MTLRenderCommandEncoder >

encoder

)

Definition at line 9 of file pass_bindings_cache_mtl.mm.

                                                                         {
  encoder_ = encoder;
}

SetRenderPipelineState()

void impeller::PassBindingsCacheMTL::SetRenderPipelineState

(

id< MTLRenderPipelineState >

pipeline

)

Definition at line 13 of file pass_bindings_cache_mtl.mm.

                                         {
  if (pipeline == pipeline_) {
    return;
  }
  pipeline_ = pipeline;
  [encoder_ setRenderPipelineState:pipeline_];
}

SetSampler()

bool impeller::PassBindingsCacheMTL::SetSampler	(	ShaderStage	stage,
		uint64_t	index,
		id< MTLSamplerState >	sampler
	)

Definition at line 99 of file pass_bindings_cache_mtl.mm.

                                                                   {
  auto& sampler_map = samplers_[stage];
  auto found = sampler_map.find(index);
  if (found != sampler_map.end() && found->second == sampler) {
    // Already bound.
    return true;
  }
  sampler_map[index] = sampler;
  switch (stage) {
    case ShaderStage::kVertex:
      [encoder_ setVertexSamplerState:sampler atIndex:index];
      return true;
    case ShaderStage::kFragment:
      [encoder_ setFragmentSamplerState:sampler atIndex:index];
      return true;
    default:
      VALIDATION_LOG << "Cannot bind buffer to unknown shader stage.";
      return false;
  }
  return false;
}

SetScissor()

void impeller::PassBindingsCacheMTL::SetScissor

(

const IRect &

scissor

)

Definition at line 138 of file pass_bindings_cache_mtl.mm.

                                                          {
  if (scissor_.has_value() && scissor_.value() == scissor) {
    return;
  }
  [encoder_
      setScissorRect:MTLScissorRect{
                         .x = static_cast<NSUInteger>(scissor.GetX()),
                         .y = static_cast<NSUInteger>(scissor.GetY()),
                         .width = static_cast<NSUInteger>(scissor.GetWidth()),
                         .height = static_cast<NSUInteger>(scissor.GetHeight()),
                     }];
  scissor_ = scissor;
}

SetTexture()

bool impeller::PassBindingsCacheMTL::SetTexture	(	ShaderStage	stage,
		uint64_t	index,
		id< MTLTexture >	texture
	)

Definition at line 75 of file pass_bindings_cache_mtl.mm.

                                                              {
  auto& texture_map = textures_[stage];
  auto found = texture_map.find(index);
  if (found != texture_map.end() && found->second == texture) {
    // Already bound.
    return true;
  }
  texture_map[index] = texture;
  switch (stage) {
    case ShaderStage::kVertex:
      [encoder_ setVertexTexture:texture atIndex:index];
      return true;
    case ShaderStage::kFragment:
      [encoder_ setFragmentTexture:texture atIndex:index];
      return true;
    default:
      VALIDATION_LOG << "Cannot bind buffer to unknown shader stage.";
      return false;
  }
  return false;
}

SetViewport()

void impeller::PassBindingsCacheMTL::SetViewport

(

const Viewport &

viewport

)

Definition at line 123 of file pass_bindings_cache_mtl.mm.

                                                               {
  if (viewport_.has_value() && viewport_.value() == viewport) {
    return;
  }
  [encoder_ setViewport:MTLViewport{
                            .originX = viewport.rect.GetX(),
                            .originY = viewport.rect.GetY(),
                            .width = viewport.rect.GetWidth(),
                            .height = viewport.rect.GetHeight(),
                            .znear = viewport.depth_range.z_near,
                            .zfar = viewport.depth_range.z_far,
                        }];
  viewport_ = viewport;
}

---

The documentation for this struct was generated from the following files:

• impeller/renderer/backend/metal/pass_bindings_cache_mtl.h
• impeller/renderer/backend/metal/pass_bindings_cache_mtl.mm